RDFグラフの検索

RDFのデータを利用するためには、データの中から求めるサブセットを取得する（検索する）手段が必要です。グラフをたどるだけでは、発見はあっても、求めるものを確実に得ることは難しいからです。

RDFトリプルとデータベース

RDFグラフに対する検索を単純に考えれば、グラフをデータベースなどに収めて条件に合致するものを照会することになります。グラフは主語―述語―目的語のトリプルの集合ですから、これらの要素をデータベースのフィールドとみなして扱うのが最もシンプルな方法でしょう。

たとえば前回のJSON-LD記述例で取り上げたグラフなら、次のようなテーブルにグラフが格納されます。

写真に関するメタデータを全部取り出すなら

SELECT * FROM tablename WHERE S='http://example.org/photo/2008/0208.jpg';

といったSQLクエリで、データ全体からこのURIを主語としたサブセットが取得できます。この写真の作成日を知りたければ、条件句に and P='http://schema.org/dateCreated'を加えることで絞込が可能です。

もちろんこれでは各要素がURIなのかリテラルなのか区別できませんし、データ型も言語コードも保持できませんから、テーブルはもう少し精密なものが必要です。それに、この方法では「写真に写っているコンサートの演奏者」などと考えたとたんにクエリは複雑になり、どんどん手に負えなくなってしまうでしょう。

RDFグラフのパターン

RDFのデータはグラフ構造を持つので、特定のデータベーステーブルを前提にするよりも、グラフの形（パターン）として取り出したい条件を考えるほうが自然です。ある写真のメタデータを表すパターンとは、次のような具合です（以下の図ではURIは接頭辞を使って短縮表記します）。

「写真に写っているコンサートの演奏者」という条件も、グラフのパターンなら簡単に表現できます。

RDFデータのグラフ全体の中から、こうしたパターンに当てはまるトリプルを取り出すことができれば、グラフの構造を利用した検索が可能になります。このようなグラフのパターンの検索方法を標準化したものがSPARQLです。SPARQLは2008年に最初のバージョンがW3C勧告となり、2013年にはSPARQL 1.1 Query Languageが勧告されています。

制約条件とフィルタ

条件を絞り込むには、変数の代わりに具体的な値を指定します。たとえばさまざまな写真メタデータを収録しているRDFデータベースを対象にしている場合、被写体のタイプをs:MusicEventとすれば、コンサート写真のみを取り出すことができます。

PREFIX s: <http://schema.org/>
SELECT * WHERE {
  ?photo ?p ?o ;
    s:about [
      a s:MusicEvent
    ] .
}

このグラフパターンは読み取れるでしょうか？　前回とりあげたTurtle構文と同じく、[]は空白ノード、aはrdf:typeを表します。SPARQLクエリのグラフパターンにおいては、空白ノードは値を取得しない変数という位置付けで、実際のグラフで対応部分がURIであっても構いません。念のため上のクエリのグラフパターンを図で確認しておきましょう。

値を直接指定するのではなく、グラフパターンで取り出した変数の値に対して条件を加えて絞り込む方法もあります。この絞り込みはFILTER句を用いて行ないます。たとえば2008年に撮影された写真のメタデータのみを取り出す場合は、まず撮影日を変数?dateで取り出した上で、その値を制約します。

PREFIX s: <http://schema.org/>
SELECT * WHERE {
  ?photo ?p ?o ;
    s:dateCreated ?date .
  FILTER ( REGEX(?date, "^2008") )
}

ここでは日付を単純リテラルとして扱い、正規表現で先頭が"2008"であるものという条件を与えて絞り込んでいます。

SPARQLでは、文字列本体が同じでもデータ型や言語タグの有無によって異なるリテラル値として扱われることに注意してください。上記のクエリでは、撮影日がデータ型xsd:dateのリテラルとして記述されているものは取得できません。データ型や言語タグの有無が不明な場合は、STR()関数を用いて値の文字列のみを取り出してからフィルタをかけます。

FILTER ( REGEX(STR(?date), "^2008") )

日付データがxsd:date型ならば、SPARQL 1.1ではyear(?date)を用いて年部分を取り出して比較することもできます。

FILTER ( year(?date) = "2008" )

このほかFILTERでは、比較演算子を用いたり!=で条件に一致しないものを取り出したりすることも可能です。

UNIONを用いたOR検索

複数条件（グラフパターン）のいずれかに該当するものを調べる場合は、グループグラフパターンをUNIONで連結します。たとえば音楽イベントとソーシャルイベントのメタデータがある場合、グラフパターンはそれぞれ次のように表現できます。

?evt ?p ?o ;
  a s:MusicEvent .

?evt ?p ?o ;
  a s:SocialEvent .

グラフパターンを{}で囲んでグループ化し、UNIONで連結したものをWHERE句内に置けばOR検索を実行できます。

PREFIX s: <http://schema.org/>
SELECT * WHERE {
  {
    ?evt ?p ?o ;
      a s:MusicEvent .
  } UNION {
    ?evt ?p ?o ;
      a s:SocialEvent .
  }
}

2つのグループグラフパターンにおいてトリプルパターン?evt ?p ?oは共通ですから、これをまとめて外に出してしまうこともできます。

PREFIX s: <http://schema.org/>
SELECT * WHERE {
  ?evt ?p ?o .
  { ?evt a s:MusicEvent . } UNION
  { ?evt a s:SocialEvent . }
}

これは、WHERE句全体がひとつの大きなグループグラフパターンとなり、その中に2つのグループグラフパターンがあるというわけです。このように、グループグラフパターンは入れ子にして扱うことができます。

必須ではない条件を表すOPTIONAL

写真が位置情報を持っていればそれを用いて地図上に表示できるので、次のようなクエリでの写真メタデータと緯度経度データの取得を考えましょう。

PREFIX s: <http://schema.org/>
SELECT * WHERE {
  ?photo ?p ?o ;
    s:location ?place .
  ?place s:geo [
    s:latitude ?lat ;
    s:longitude ?long
  ] .
}

このクエリで緯度経度を含めたメタデータを取り出せるのですが、「位置情報があれば地図も表示するけれど、なければ地図なしで写真メタデータのみを表示する」という場合、このままではうまく行きません。図を見ると分かるように、位置情報がないデータはこのグラフパターンに当てはまらなくなってしまうからです。

ある条件は必須でない（オプション）としたい場合は、その条件を表すグラフパターンを{}でグループ化し、OPTIONALキーワードで親パターンに加えます。

PREFIX s: <http://schema.org/>
SELECT * WHERE {
  ?photo ?p ?o ;
    s:location ?place .
  OPTIONAL {
    ?place s:geo [
      s:latitude ?lat ;
      s:longitude ?long
    ] .
  }
}

このクエリを使えば、位置情報のない写真については?lat、?longの値は空として結果に含んだメタデータが得られます。

データの来歴と名前付きグラフ

複数のSPARQLエンドポイントから得られたデータを組み合わせて情報を提供するようなアプリケーションを構築する場合、それぞれのデータをもともとどこから取得したか（来歴）を把握しておくことは重要です。SPARQLクエリの結果はトリプルではなく値の集合となってしまうので、変数名が同じだと元データの区別がつかなくなり、思わぬ矛盾や不整合に行き当たることがあるからです。来歴の確認のためにも、複数エンドポイントを利用する場合はグラフURIも合わせて取得しておくとよいでしょう。

来歴は、SPARQLクエリの結果だけでなくRDFグラフ全般についても重要な情報です。RDFは誰もが何について何を述べてもよい（Anyone can say anything about anything）世界なので、同じURIを主語にしたトリプル／グラフがいろいろなところで記述される可能性があります。これらを集めることでグラフが連結され、ばらばらだった情報がつながるのがRDFの大きな力ですが、来歴をきちんと管理していないと、どの情報（トリプル）が正確なのか、情報が古くなっていないのかといったことが分からなくなってしまうのです。

この来歴管理のため、SPARQLでの検索だけでなくRDFデータそのものにもグラフURIを利用することができます。これについては、回を改めて検討してみます。